sonar-dummy-gradle-oss/build.gradle at master · SonarSource/sonar-dummy-gradle-oss · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
plugins {
  id 'com.github.hierynomus.license' version '0.16.1'
  id 'signing'
  id "com.jfrog.artifactory" version "6.0.4"
  id "org.cyclonedx.bom" version "3.2.4"
  id "org.sonarqube" version "7.3.1.8318"
}

// Analyze with SonarQube!
sonarqube {
  properties {
    property 'sonar.projectName', 'sonar-dummy-gradle-oss'
    property 'sonar.projectKey', 'SonarSource_sonar-dummy-gradle-oss'
    property 'sonar.organization', 'sonarsource'
  }
}

allprojects {
  apply plugin: 'com.jfrog.artifactory'
  apply plugin: 'maven-publish'
  apply plugin: "org.cyclonedx.bom"

  afterEvaluate {
    signing {
      def signingKeyId = findProperty("signingKeyId")
      def signingKey = findProperty("signingKey")
      def signingPassword = findProperty("signingPassword")
      useInMemoryPgpKeys(signingKeyId, signingKey, signingPassword)
      required {
        return gradle.taskGraph.hasTask(":artifactoryPublish")
      }
      sign publishing.publications
    }
  }

  tasks.withType(Sign) {
    onlyIf {
      return !artifactoryPublish.skip && gradle.taskGraph.hasTask(":artifactoryPublish")
    }
  }
}

subprojects {
  apply plugin: 'java'
  apply plugin: "jacoco"
  apply plugin: 'com.github.hierynomus.license'
  apply plugin: 'signing'

  java {
    withJavadocJar()
    withSourcesJar()
  }

  compileJava {
    options.release = 8
    options.encoding = 'UTF-8'
  }

  tasks.withType(Javadoc) {
    options.addStringOption('Xdoclint:none', '-quiet')
  }

  license {
    header = rootProject.file('HEADER')
    strictCheck true
    mapping {
      java = 'SLASHSTAR_STYLE'
    }
    includes(['**/*.java'])
  }

  def bomFile = layout.buildDirectory.file('reports/bom.json')
  cyclonedxBom {
    // cyclonedx-gradle-plugin 2.x+ defaults to build/reports/cyclonedx/bom.json; pin it back explicitly.
    jsonOutput.set(bomFile)
    outputs.file bomFile
  }
  def bomArtifact = artifacts.add('archives', bomFile.get().asFile) {
    type 'json'
    classifier 'cyclonedx'
    builtBy 'cyclonedxBom'
  }
  publishing {
    publications {
      mavenJava(MavenPublication) {
        artifact bomArtifact
      }
    }
  }
}

artifactory {
  clientConfig.setIncludeEnvVars(true)
  clientConfig.setEnvVarsExcludePatterns('*password*,*PASSWORD*,*secret*,*MAVEN_CMD_LINE_ARGS*,sun.java.command,*token*,*TOKEN*,*LOGIN*,*login*,*signing*')
  contextUrl = System.getenv('ARTIFACTORY_URL')
  publish {
    repository {
      repoKey = System.getenv('ARTIFACTORY_DEPLOY_REPO')
      username = System.getenv('ARTIFACTORY_DEPLOY_USERNAME')
      password = System.getenv('ARTIFACTORY_DEPLOY_ACCESS_TOKEN')
    }
    defaults {
      properties = [
        'build.name'      : 'sonar-dummy-gradle-oss',
        'build.number'    : System.getenv('BUILD_NUMBER'),
        'pr.branch.target': System.getenv('PULL_REQUEST_BRANCH_TARGET'),
        'pr.number'       : System.getenv('PULL_REQUEST_NUMBER'),
        'vcs.branch'      : System.getenv('GIT_BRANCH'),
        'vcs.revision'    : System.getenv('GIT_COMMIT'),
        'version'         : version
      ]
      publications('mavenJava')
      publishPom = true
      publishIvy = false
    }
    clientConfig.info.addEnvironmentProperty('ARTIFACTS_TO_PUBLISH', 'org.sonarsource.dummy:sonar-dummy-gradle-oss-plugin:jar,org.sonarsource.dummy:sonar-dummy-gradle-oss-plugin:json:cyclonedx')
  }

  clientConfig.info.setBuildName('sonar-dummy-gradle-oss')
  clientConfig.info.setBuildNumber(System.getenv('BUILD_NUMBER'))
  // The name of this variable is important because it's used by the delivery process when extracting version from Artifactory build info.
  clientConfig.info.addEnvironmentProperty('PROJECT_VERSION', "${version}")
}